FINISH
/clear
  
! Parte 1, disco singolo

Ri = 0.10     !m raggio interno 
Re = 0.20     !m raggio esterno
H =  0.05     !m spessore
Pi=  5e6      !pressione interna [PA]
Pe=  10e6     !pressione esterna [PA]
n =  1000     !giri/min
ndivy = 5     !numero di divisioni sul semi-spessore
ndivx = 50    !numero di divisioni in direzione radiale
Eacc =  200e9 ! Modulo di young acciaio
Niacc = 0.3	  ! Coefficiente di Poisson acciaio
Roacc = 7800  ! Densità acciaio

/PREP7  !ingresso ambiente di preprocessing

ET,1,PLANE182

KEYOPT,1,3,1  !axisymmetric

MP,EX,  1,Eacc  
MP,PRXY,1,Niacc  
MP,DENS,1,Roacc 

!creazione keypoints
K, 101, Ri, 0
K, 102, Re, 0
K, 103, Re, H/2
K, 104, Ri, H/2

!creazione linee
LSTR, 101, 102  !L1
LSTR, 102, 103  !L2
LSTR, 103, 104  !L3
LSTR, 104, 101  !L4

!creazione aree
AL, 1,2,3,4  

!divisione linee
LESIZE,2,,,ndivy,  
LESIZE,4,,,ndivy,
LESIZE,1,,,ndivx,-5, 
LESIZE,3,,,ndivx,-5, 

!crazione mesh
MSHKEY,1
AMESH,all

!vincolo di simmetria
DL,1, ,UY,   

!Assegnazione pressioni interne ed esterne
SFL,4,PRES,Pi 
SFL,2,PRES,Pe 

!velocità angolare attorno all'asse Y
OMEGA,0,n*6.28/60,0

FINISH  
/SOL    !ingresso ambiente di soluzione

!calcolo soluzione
SOLVE   

FINISH  
/POST1  !ingresso ambiente di postelaborazione

!definizione path radiale
PATH,raggio,2,7,100,     !100 righe x 7 colonne
PPATH, 1, ,Ri,0,0        !punto iniziale
PPATH, 2, ,Re,0,0        !punto finale

PDEF,Sigma_R, S,  X,AVG  !map onto path
PDEF,Sigma_C, S,  Z,AVG  
PDEF,Sigma_Eq,S,EQV,AVG

!creazione del grafico
PLPATH,Sigma_R,Sigma_C,Sigma_Eq  

/EOF ! Fine analisi disco singolo